# Packager: Justin "juster" Davis <jrcd83@gmail.com>
# $Id: PKGBUILD 150752 2012-02-21 19:43:15Z juster $

pkgname=perl-lwp-protocol-https
pkgver=6.03
pkgrel=1
pkgdesc="Provide https support for LWP::UserAgent"
arch=(any)
license=(PerlArtistic GPL)
options=(!emptydirs)
depends=('perl>=5.8.1' 'perl-io-socket-ssl>=1.54' 'perl-mozilla-ca>=20110101'
         'perl-net-http' 'perl-libwww>=6.04')
url=https://metacpan.org/release/LWP-Protocol-https
source=("http://search.cpan.org/CPAN/authors/id/G/GA/GAAS/LWP-Protocol-https-${pkgver}.tar.gz")
md5sums=(2a9341732172da290fe1b5af98a015a7)
sha512sums=(531326ba359e242d552f091f270ad4d5b80090093b3b2c89fec5f93f9e7f8807b5db95590f620d026e9090794f3e7775bf27480cba087af170207d99e25e6c14)
_distdir="${srcdir}/LWP-Protocol-https-${pkgver}"

build()
(
    export PERL_MM_USE_DEFAULT=1 PERL5LIB=""                 \
      PERL_AUTOINSTALL=--skipdeps                            \
      PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'"     \
      PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
      MODULEBUILDRC=/dev/null

    cd "$_distdir"
    /usr/bin/perl Makefile.PL
    make
)

check()
(
    export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
    cd "$_distdir"
    make test
)

package() {
    cd "$_distdir"
    make DESTDIR="$pkgdir" install
    find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}

# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et:
