# $Id: PKGBUILD 161252 2012-06-08 06:39:33Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>

pkgname=kdeutils-printer-applet
pkgver=4.8.4
pkgrel=1
pkgdesc='System tray icon for managing print jobs'
url='http://kde.org/applications/system/printerapplet/'
arch=('any')
url='http://www.kde.org'
license=('GPL' 'LGPL' 'FDL')
depends=('kdebase-runtime' 'kdebindings-python2' 'system-config-printer-common')
makedepends=('cmake' 'automoc4')
groups=('kde' 'kdeutils')
source=("http://download.kde.org/stable/${pkgver}/src/printer-applet-${pkgver}.tar.xz")
sha1sums=('451bb3d658a447c454918ea5b0299f1e85b8cfd2')

build() {
  cd "${srcdir}"
  mkdir build
  cd build
  cmake ../printer-applet-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DPYTHON_EXECUTABLE=/usr/bin/python2
  make
}

package() {
  cd $srcdir/build
  make DESTDIR=$pkgdir install
  cd $srcdir/build/doc
  make DESTDIR=$pkgdir install

  # Fix python 2 path
  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
    "${pkgdir}"/usr/share/apps/printer-applet/{authconn,debug,monitor,printer-applet,statereason}.py
}
