PERLSTYLE(7)

NAME
perlstyle - Perl 風格指南

DESCRIPTION 描述
每個程式員當然都會有自己的編程風格，但是有一些一般性的原則可以使得我們的程式更易於閱讀，理解，以及維護。

最重要的是使用 -w 選項. 如果必須關閉該選項，可以用 "no warnings" 或變量 $^W 來在一定的代碼段中關閉它. 你還應該使用 "use strict" 除非你清楚不使用它的理由. "use sigtrap" 和 "use diagnostics" 也是非常有用的.

關於代碼美學, Larry 大概只強烈的關心一件事情：多行塊的結束花括號應該與開始的關鍵字對齊. 除了這個, 還有一些不是那麼重要的事情:

•   4-列縮進.

•   如果可能的話，開始的花括號與關鍵詞最好放在同一行，否則對齊.

•   多行的塊的開始的花括號之前應當有空格

•   單行的塊放在一行，包括花括號.

•   分號前不要空格.

•   在短的單行塊中省略分號.

•   操作符周圍打空格.

•   在「復合」下標周圍打空格 (在括號中).

•   在不同功能的塊之間打空行.

•   else另起一行寫

•   函數與括號間不要空格

•   每個逗號後打空格.

•   長句子在操作符後截斷 ( "and" 和 "or" 除外).

•   關閉括號後打空格.

•   相關項之間以列對齊.

•   在不影響清晰的情況下盡量減少標點符號.

Larry 這樣做當然有他的原因, 不過他沒有要求別人都和他一樣.

以下意見供您參考:

•   可以那樣做並不意味著應該那樣做. Perl 設計為作每件事都可以用好幾種方法, 你應該選擇最可讀的一種. 例如

        open(FOO,$foo) || die "Can't open $foo: $!";

    好於

        die "Can't open $foo: $!" unless open(FOO,$foo);

    因為第二種辦法掩蓋了句子中的主要內容。另一方面

        print "Starting analysis\n" if $verbose;

    好於

        $verbose && print "Starting analysis\n";

    因為主要關鍵不在於是否使用者輸入了 -v。

    類似的，因為一個操作符允許使用預設參數，不意味著你必須使用預設值。預設值是為懶惰的系統程式員書寫只運行一次的程式準備的。如果你需要你的程式盡量可讀，考慮給出參數。

    根據相同的原則，在很多地方即使你可以忽略括號也不意味著你應當這樣做：

        return print reverse sort num values %array;
        return print(reverse(sort num (values(%array))));

    如果有疑義，使用括號。至少它使得可憐的笨蛋能在 vi 中使用 % 鍵來跳轉

    甚至你沒有疑義的時候，為那個將來維護你的代碼的家伙的精神健康考慮一下吧，並且他有可能把括號放錯地方。

•   在程式中使用 last 跳出，而不要在開始和結束時用奇怪的跳轉退出循環。把它 "縮出" 幾格以利於察看:

        LINE:
            for (;;) {
                statements;
              last LINE if $foo;
                next LINE if /^#/;
                statements;
            }

•   別害怕使用循環標記--它們用來增強可讀性並且允許多層循環中斷. 參見前例.

•   避免在空上下文中使用 grep() (或 map()) 或 `反引號` , 那樣，你就丟棄了它們的返回值. 使用它們是為了得到返回值，否則，使用 foreach() 或是 system() 好了.

•   考慮移植的時候，某些特性可能不是在所有的機器上都能夠得到支持, 這時可以用 eval來測試. 如果你知道提供特定功能的版本或是補丁, 你可以察看 $] (也就是 "English" 中的 $PERL_VERSION) 來確定當前的版本. "Config" 模塊也會提供perl在安裝時 Configure 程式測得的值.

•   使用明確的標識符，你要是想不起來標識符的意思，那就麻煩了。

•   短標識符如 $gotit 雖然沒什麼不好, 但是用下劃線來分割單詞可以增加可讀性. 如 $var_names_like_this 好於 $VarNamesLikeThis,對不以英語為母語的人更是如此.同樣，在使用 VAR_NAMES_LIKE_THIS 時也要遵循這個規則。

    包名稱有時不遵守這個約定. Perl 為 "pragma" 保留小寫的包名稱，比如 integer 和 strict. 其他模塊名稱應該用大寫字母開始，但是一般不用下劃線來分隔，因為當使用模塊名來作檔名時，這在某些系統會出現錯誤.

•   使用大小寫可以區分變量的作用域。例如:

        $ALL_CAPS_HERE   常量 (小心！不要與 perl 變量沖突!)
        $Some_Caps_Here  包作用域 global/static
        $no_caps_here    函數作用域 my() 或 local() 變量

    函數和方法名多用小寫. 如, $obj->as_string().

    用下劃線開始的函數名或變量名，表示該函數或變量只能在定義它的包中使用.

•   如果你的正則表達式較復雜，用 "/x" 來增加注釋行或空行以利於閱讀. 當其中有很多斜槓或反斜槓時，不要用反斜槓來作正則表達式的定界符.

•   使用 "and" 和 "or" 操作符以減少使用括號, 盡量少用 && 和 ||. 調用子程式時盡量少用"&"和括號，可以把子程式當做函數或列表操作符來調用.

•   使用 here documents 代替大量的 print() 語句.

•   相關語句用列對齊方式來書寫，特別是當一行放不下的時候.

        $IDX = $ST_MTIME;
        $IDX = $ST_ATIME       if $opt_u;
        $IDX = $ST_CTIME       if $opt_c;
        $IDX = $ST_SIZE        if $opt_s;

        mkdir $tmpdir, 0700 or die "can't mkdir $tmpdir: $!";
        chdir($tmpdir)      or die "can't chdir $tmpdir: $!";
        mkdir 'tmp',   0777 or die "can't mkdir $tmpdir/tmp: $!";

•   總是檢測返回值. 錯誤訊息被送往 STDERR, 包括出錯的程式、失敗的系統調用及參數、並且（非常重要的）包括標準錯誤訊息. 這裏是一個簡單而完整的例子:

        opendir(D, $dir)     or die "can't opendir $dir: $!";

•   把翻譯列表以列對齊方式排列:

        tr [abc]
           [xyz];

•   考慮可重用性. 請考慮使用模塊或對象. 考慮使用 use strict 和 use warnings (或 -w) 使代碼清晰明確. 考慮改變世界觀。

•   要一致，要相容。

•   要漂亮，要美觀。

譯者
redcandle <redcandle51@chinaren.com> 20010530

中文手冊頁翻譯計劃
http://cmpp.linuxforum.net