# $Id: PKGBUILD 61887 2012-01-09 19:07:15Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>

pkgname=vdrift-data
_pkgname=vdrift
pkgver=2011.10.22
pkgrel=3
epoch=2
pkgdesc="An open source driving simulation made with drift racing in mind (data files)"
arch=('any')
url="http://vdrift.net/"
license=('GPL')
depends=('bullet' 'curl' 'sdl_gfx' 'sdl_image' 'glew' 'libvorbis')
makedepends=('scons' 'boost' 'asio')
source=(http://downloads.sourceforge.net/sourceforge/$_pkgname/$_pkgname-${pkgver//./-}.tar.bz2)
md5sums=('6f8806ab1be303e9e1e47522c9eee890')

build() {
  cd "$srcdir"/$_pkgname-${pkgver//./-}

  # select arch
  if [ `uname -m` = "x86_64" ]; then
    _sconsarch="a64"
  else
    _sconsarch="686"
  fi

  #sed -i 's/glGenerateMipmap/glGenerateMipmapEXT/g' src/texture.cpp
  #sed -i '/types.h/d' src/http.h

  # build and install
  scons $MAKEFLAGS \
    "destdir"="$pkgdir" \
    "arch"=$_sconsarch \
    "release"=1 \
    "force_feedback"=1 \
    "prefix"=/usr \
    "datadir"=share/$_pkgname/ \
    "extbullet"=1
}

package() {
  cd "$srcdir"/$_pkgname-${pkgver//./-}

  scons install

  rm -r $pkgdir/usr/bin
}
# vim: sw=2:ts=2 et:
