# $Id: PKGBUILD 68606 2012-03-29 11:00:45Z mtorromeo $
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Contributor: Daniele Paolella <dp@mcrservice.it>

pkgname=supervisor
pkgver=3.0a12
pkgrel=1
pkgdesc="A system for controlling process state under UNIX"
arch=('any')
url="http://supervisord.org"
license=('custom')
depends=('python2-distribute' 'python2-meld3')
backup=('etc/supervisord.conf')
source=("http://pypi.python.org/packages/source/s/$pkgname/$pkgname-$pkgver.tar.gz"
        'supervisord'
        'supervisord.conf')

build() {
	cd "$srcdir/$pkgname-$pkgver"
	rm -rf "supervisor/medusa/"{debian,demo,docs,test}
	find -type f -name "*.py" -exec sed -i 's|/usr/bin/env python|/usr/bin/env python2|' {} \;
	python2 setup.py install -O1 --prefix=/usr --root="$pkgdir"
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	install -D -m600 "$srcdir/supervisord.conf" "$pkgdir/etc/supervisord.conf"
	install -D "$srcdir/supervisord" "$pkgdir/etc/rc.d/supervisord"
	install -d "$pkgdir/usr/share/licenses/$pkgname"
	install -d "$pkgdir/var/log/$pkgname"
	install -d "$pkgdir/etc/supervisor.d"
	mv LICENSES.txt COPYRIGHT.txt "$pkgdir/usr/share/licenses/$pkgname"
}

md5sums=('eb2ea5a2c3b665ba9277d17d14584a25'
         '38931759dc31fc1feaccccaa32059f38'
         'd8300b00cc467039f3dd746b9ad41f55')
sha256sums=('de60eee3c460b379aa8493083b59d31b29f2c4267730db29b6f9dea22642b3b4'
            '44ef896edfd9b22d4752287bd635225584257e3f869f48772564e12903060207'
            '9b665fc83a84a6071d1da09db9db75f3894881aee675fc45e7428bef1a2d7314')
