# $Id: PKGBUILD 64558 2012-02-16 07:28:57Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Douglas Soares de Andrade <dsandrade@gmail.com>
# Contributor: Douglas Soares de Andrade <dsandrade@gmail.com>

pkgbase=python-pyserial
pkgname=('python-pyserial' 'python2-pyserial')
pkgver=2.6
pkgrel=2
pkgdesc="Multiplatform Serial Port Module for Python"
arch=('any')
url="http://pyserial.sf.net"
license=('custom:PYTHON')
makedepends=('python2' 'python')
source=(http://pypi.python.org/packages/source/p/pyserial/pyserial-$pkgver.tar.gz)
md5sums=('cde799970b7c1ce1f7d6e9ceebe64c98')

build() {
  true
}

package_python-pyserial() {
  depends=('python')

  cd $srcdir/pyserial-$pkgver
  python setup.py install --root=$pkgdir
  install -D -m644 LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/LICENSE.txt
}

package_python2-pyserial() {
  depends=('python2')

  cd $srcdir/pyserial-$pkgver
  python2 setup.py install --root=$pkgdir
  install -D -m644 LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/LICENSE.txt
  mv $pkgdir/usr/bin/miniterm.py $pkgdir/usr/bin/miniterm2.py
}
