# Packager: Justin "juster" Davis <jrcd83@gmail.com>
# $Id: PKGBUILD 65652 2012-02-21 18:45:26Z juster $

pkgname=perl-path-class
pkgver=0.25
pkgrel=1
pkgdesc="Cross-platform path specification manipulation"
arch=(any)
license=(PerlArtistic GPL)
options=(!emptydirs)
depends=('perl')
url=https://metacpan.org/release/Path-Class
source=("http://search.cpan.org/CPAN/authors/id/K/KW/KWILLIAMS/Path-Class-${pkgver}.tar.gz")
md5sums=(91517fdac5262e8665ae2ba9f507824b)
sha512sums=(e4a940225ad55a373e2f15b7485765bcbbc77a8e9455c7729e66a5c615257f3c17e509a863ec68e89a6923ba399eef110db3755c74f404cdc5c5a4695d718208)
_distdir="${srcdir}/Path-Class-${pkgver}"

build()
(
    export PERL_MM_USE_DEFAULT=1 PERL5LIB=""                 \
      PERL_AUTOINSTALL=--skipdeps                            \
      PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'"     \
      PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
      MODULEBUILDRC=/dev/null

    cd "$_distdir"
    /usr/bin/perl Build.PL
    ./Build
)

check()
(
    export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
    cd "$_distdir"
    ./Build test
)

package() {
    cd "$_distdir"
    ./Build install
    find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}

# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et:
