# $Id: PKGBUILD 69394 2012-04-15 16:09:21Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>

pkgname=ocrfeeder
pkgver=0.7.9
pkgrel=1
pkgdesc="GTK+ document layout analysis and optical character recognition application"
arch=('any')
url="http://live.gnome.org/OCRFeeder"
license=('GPL')
depends=('python2-pyenchant' 'pygoocanvas' 'python2-gtkspell' 'python-imaging' 'python-reportlab' 'ghostscript' 'unpaper' 'sane' 'desktop-file-utils')
makedepends=('intltool' 'gnome-doc-utils')
optdepends=('tesseract: character recognition'
            'ocrad: character recognition'
            'gocr: character recognition'
            'cuneiform: character recognition')
install=$pkgname.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
sha256sums=('c410e4463a6e9562c22dad8f78eef94f50b38d076c5eec6695d7109f8ef2c905')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i 's@^#!.*python$@#!/usr/bin/python2@' bin/ocrfeeder*.in src/ocrfeeder/odf/*.py

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
              --disable-scrollkeeper \
              PYTHON=python2
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
  mkdir -p "$pkgdir/usr/share/pixmaps"
  ln -s ../ocrfeeder/icons/ocrfeeder.svg "$pkgdir/usr/share/pixmaps/ocrfeeder.svg"
}
