# $Id: PKGBUILD 74353 2012-07-25 14:56:53Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Timm Preetz <timm@preetz.us>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=netbeans
pkgver=7.2
_subpkgver=201207171143
pkgrel=1
pkgdesc='IDE for Java, PHP, Groovy, C, C++ and Python'
arch=('any')
url='http://netbeans.org/'
license=('CDDL')
depends=('java-environment' 'ttf-bitstream-vera' 'libxtst')
makedepends=('gendesk>=0.4.2')
optdepends=('php: for developing programs in php'
            'groovy: for developing programs in groovy'
            'python: for developing programs in python'
            'lib32-glibc')
install=$pkgname.install
options=(!strip)
source=("http://download.netbeans.org/$pkgname/$pkgver/final/zip/$pkgname-$pkgver-$_subpkgver-ml.zip")
sha256sums=('91555714fc5384ae9c409687324ec5950b1495c55e84b5cb60b6c190040fcaa3')

build() {
  cd "$srcdir"
  gendesk -n
}

package() {
  cd "$srcdir/$pkgname"
  mkdir -p "$pkgdir/usr/bin" "$pkgdir/usr/share/applications"
  cp -r "../$pkgname" "$pkgdir/usr/share"
  install -Dm644 "../$pkgname.desktop" \
    "$pkgdir/usr/share/applications/$pkgname.desktop"
  install -Dm644 "nb/$pkgname.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
  ln -s "/usr/share/$pkgname/bin/$pkgname" "$pkgdir/usr/bin/$pkgname"
  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et:
