# $Id: PKGBUILD 73168 2012-07-02 17:56:24Z bpiotrowski $
# Maintainer:  Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>

pkgname=lxde-common
pkgver=0.5.5
pkgrel=2
pkgdesc='Common files of the LXDE Desktop'
arch=('any')
url='http://lxde.org/'
license=('GPL2')
groups=('lxde')
backup=(etc/xdg/lxsession/LXDE/desktop.conf
        etc/xdg/lxsession/LXDE/autostart)
depends=('libx11' 'glib2' 'lxde-icon-theme' 'lxsession')
makedepends=('automake')
source=(http://downloads.sourceforge.net/lxde/${pkgname}-${pkgver}.tar.gz
        startlxde.patch)
md5sums=('e51a6b2a815a89fda1f497b509465a97'
         '523b8fc9fd4b908236f67775ca6fc06d')

build() {
    cd $srcdir/$pkgname-$pkgver
    autoreconf
    ./configure --sysconfdir=/etc --prefix=/usr
    make
    patch -Np0 -i $srcdir/startlxde.patch
}

package() {
    cd $srcdir/$pkgname-$pkgver
    make DESTDIR=$pkgdir install
    install -Dm644 lxde-logout.desktop \
      $pkgdir/usr/share/applications/lxde-logout.desktop
}
