# $Id: PKGBUILD 73079 2012-06-30 13:15:02Z kkeen $
# Maintainer: Kyle Keen <keenerd@gmail.com>
# Contributor: PepeSmith
# Contributor: Aron Asor <aronasorman at gmail.com>
# Contributor: Chris Brannon <chris@the-brannons.com>
# Contributor : Douglas Soares de Andrade <dsa@aur.archlinux.org>
 
pkgname=ipython
pkgver=0.13
pkgrel=1
pkgdesc="An enhanced Interactive Python shell."
arch=('any')
url="http://ipython.org"
provides=('ipython3')
replaces=('ipython3')
license=('Modified BSD')
depends=('python' 'sqlite' 'python-distribute')
optdepends=("wxpython: needed for ipythonx and ipython-wx"
            "python-nose: if you want to run IPython's test suite"
            "pyqt: for ipython-qtconsole"
            "sip: for ipython-qtconsole"
            "python-pygments: for ipython-qtconsole"
            "python-pyzmq: for ipython-qtconcole"
            "python-tornado: for ipython notebook")
source=("http://archive.ipython.org/release/$pkgver/ipython-$pkgver.tar.gz")
md5sums=('490ccc2da9d6de9c37c7df05c1197ac5')

package() {
  cd "$srcdir/ipython-$pkgver"

  python setup.py install --prefix=/usr --root="$pkgdir" --optimize=0
  find "$pkgdir/" -name '*.pyc' -delete
  find "$pkgdir/" -type d -empty -delete

  cd "$pkgdir/usr/bin/"
  mv ipcluster3        ipcluster
  mv ipcontroller3     ipcontroller
  mv ipengine3         ipengine
  mv iplogger3         iplogger
  mv iptest3           iptest
  mv ipython3          ipython
  mv irunner3          irunner
  mv pycolor3          pycolor
}
