# $Id: PKGBUILD 69664 2012-04-22 04:59:18Z allan $
# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: enderst <enderst@gmail.com>

pkgname=gpodder
pkgver=2.20.1
pkgrel=1
pkgdesc='A podcast receiver/catcher'
license=('GPL3')
arch=('any')
url='http://gpodder.org/'
depends=('pygtk' 'python2-feedparser' 'dbus-python' 'python2-mygpoclient')
makedepends=('intltool' 'imagemagick' 'help2man')
optdepends=('libgpod: for ipod support'
            'pymad: for ipod support'
            'mplayer: for ipod video support'
            'python-imaging: rockbox cover art support'
            'vorbis-tools: for ogg tag updating and converting to mp3'
            'lame: for converting ogg to mp3'
            'gnome-bluetooth: transfer podcast via bluethooth'
            'pywebkitgtk: render shownotes'
            'python-eyed3: for ipod support')
            # pymtp: for mtp support (AUR only)
source=(http://gpodder.org/src/gpodder-${pkgver}.tar.gz)
md5sums=('6ddb62c4d61023f93c12646bc762e61b')

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  PYTHON=python2 make DESTDIR=${pkgdir}/ install

  sed -i -e 's|#!/usr/bin/python$|#!/usr/bin/python2|' \
         -e 's|#!/usr/bin/env python$|#!/usr/bin/env python2|' \
    $(find $pkgdir/usr/lib/python2.7/site-packages/gpodder/ -name '*.py')
}
