setenv bootcmd run flash_ubifs
setenv bootdelay 0
setenv verify no
setenv stdin serial
setenv stdout serial
setenv stderr serial
setenv baudrate 115200

setenv net_nfs tftp 200000 \${bootfile}\;run net_nfs_args addip\;bootm \${kernel_ram_addr} - \${fdt_addr}
setenv net_nfs_args setenv bootargs console=ttyPSC3,115200 root=/dev/nfs rw nfsroot=\${serverip}:\${net_nfs_rootpath}
setenv bootfile uImage
setenv net_nfs_rootpath /srv/nfs/rfs

setenv net_ubifs tftp 200000 \${bootfile}\;run ubifsargs addip\;bootm \${kernel_ram_addr} - \${fdt_addr}
setenv flash_ubifs run ubifsargs addip\; bootm \${kernel_flash_addr} - \${fdt_addr}
setenv ubifsargs setenv bootargs console=ttyPSC3,115200 ubi.mtd=0 root=ubi0:rootfs rw rootfstype=ubifs quiet

setenv flash_nfs run flash_nfs_args addip\; bootm \${kernel_flash_addr} - \${fdt_addr}
setenv flash_nfs_args setenv bootargs console=ttyPSC3,115200 root=/dev/nfs rw nfsroot=\${serverip}:\${flash_nfs_rootpath}
setenv flash_nfs_rootpath /srv/nfs/rfs

setenv addip setenv bootargs \${bootargs} ip=\${ipaddr}:\${serverip}:\${gatewayip}:\${netmask}:\${hostname}:\${netdev}:off panic=1
setenv ethact FEC ETHERNET
setenv netdev eth0

setenv kernel_flash_addr ff700000
setenv kernel_ram_addr 200000
setenv fdt_addr fffc0000

saveenv
